Tutoriál – užívání hodin reálného času DS1307 a DS3231 s Arduinem

Server Tronixstuff před nedávnem zveřejnil návod, jak se dají s Arduinem ovládat moduly reálného času. Jeho první díl vám dnes přinášíme.

Podíváme se na dva moduly, Maxim DS1307 (Součástí například tohoto kitu se senzory):

Maxim DS1307

a DS3231:

DS3231

Základní rozdíl mezi oběma integrovanými obvody hodin reálného času se týká přesnosti sledování času. Modul DS1307 funguje výborně, nicméně teplota okolí může ovlivnit frekvenci oscilátoru, který řídí vnitřní počítač DS1307.

To se může jevit jako problém, ve skutečnosti to ale znamená, že se hodinyposunou přibližně o pět minut v měsíci. Modul DS3231 je výrazně přesnější, protože má vnitřní oscilátor, který neovlivňují vnější faktory a proto má odchylky nanejvýš několik minut ročně. Pokud užíváte modul DS 1307, nemusíte si zoufat, přes uvedený nedostatek jde o hodnotný kus, který vám bude dobře sloužit.

Oba moduly dostanete od výrobce Tronixlabs s vestavěnou baterií, ta je ale spíše z levnějších a déle než dva měsíce byste na ni neměli spoléhat. Pokud instalujete modul v rámci dlouhodobějšího projektu, je vhodnější zakoupit novou baterii typu CR2032 nebo CR2025 a tou v modulu nahradit baterii od výrobce.

Krom toho, že sledují čas a datum, mají tyto moduly také malou EEPROM, „budík“ (resp. má ho pouze DS3231) a schopnost generovat čtvercové vlny různých frekvencí. O tom všem pojedná náš druhý tutoriál.

Připojování modulu k Arduinu

Oba modely používají sběrnici I2C, která umožňuje velmi snadné připojení. Pokud si nejste v práci s ní a s Arduinem dostatečně jistí, podívejte se na příslušné návody (kapitoly 20 a 21) nebo na sedmnáctou kapitolu mé knihy „Arduino Workshop“. (Poznámka redakce – v češtině si můžete o I2C sběrnici přečíst více ZDE).

Dále musíte identifikovat, které piny na Arduinu nebo kompatibilní desce sběrnice I2C užívá – jsou to piny značené SDA (data) a SCL (hodiny). Na Arduinu a kompatibilních deskách jde o piny A4 a A5 pro data a pro hodiny:

Připojení k Arduinu Uno

Pokud užíváte Arduino Mega, půjde o piny D20 a D21 pro data a pro hodiny:

Připojení k Arduinu Mega

Na přístrojích kompatibilních s Pro Mini půjde o piny A4 a A5 pro data a pro hodiny. Jsou paralelní k hlavním pinům, jak vidíte níže:

Přiopojení k ProMini

Modul DS1307

Jestliže používáte modul DS1307, potřebujete kabely připájet k desce nebo na pár pinů, abyste mohli používat jumper kabely. Poté připojíte piny SCL, SDA, Vcc a GND k Arduinu.

Modul DS3231

Připojování tohoto modulu je snadné, protože piny jsou na desce továrně instalovány. Stačí vést kabely opět z SCL a SDA do Arduina a znovu z Vcc modulu a GND pinů do 5V nebo 3,3 V a GND desky. Ty jsou nicméně duplikovány na druhé straně kvůli pájení vlastních kabelů.

Oba moduly mají potřebné pull-up rezistory, takže nemusíte dodávat vlastní. Jako v případě každého nástroje připojeného ke sběrnici I2C, snažte se používat co nejkratší SDA a SLC kabely.

Čtení a zapisování času v modulu hodin reálného času

Jakmile modul úspěšně připojíte, potřebujete si stáhnout následující sketch. Komentáře a funkce se sice týkají pouze DS3231, ale kód funguje také pro DS1307.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68
// Convert normal decimal numbers to binary coded decimal

byte decToBcd(byte val){
    return( (val/10*16) + (val%10) );
}

// Convert binary coded decimal to normal decimal numbers
byte bcdToDec(byte val){
    return( (val/16*10) + (val%16) );
}

void setup(){
    Wire.begin();
    Serial.begin(9600);
    // set the initial time here:
    // DS3231 seconds, minutes, hours, day, date, month, year
    // setDS3231time(30,42,21,4,26,11,14);
}

void setDS3231time(byte second, byte minute, byte hour, byte dayOfWeek, byte dayOfMonth, byte month, byte year){
    // sets time and date data to DS3231
    Wire.beginTransmission(DS3231_I2C_ADDRESS);
    Wire.write(0); // set next input to start at the seconds register
    Wire.write(decToBcd(second)); // set seconds
    Wire.write(decToBcd(minute)); // set minutes
    Wire.write(decToBcd(hour)); // set hours
    Wire.write(decToBcd(dayOfWeek)); // set day of week (1=Sunday, 7=Saturday)
    Wire.write(decToBcd(dayOfMonth)); // set date (1 to 31)
    Wire.write(decToBcd(month)); // set month
    Wire.write(decToBcd(year)); // set year (0 to 99)
    Wire.endTransmission();
}

void readDS3231time(byte *second, byte *minute, byte *hour, byte *dayOfWeek, byte *dayOfMonth, byte *month, byte *year){
    Wire.beginTransmission(DS3231_I2C_ADDRESS);
    Wire.write(0); // set DS3231 register pointer to 00h
    Wire.endTransmission();
    Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
    // request seven bytes of data from DS3231 starting from register 00h
    *second = bcdToDec(Wire.read() & 0x7f);
    *minute = bcdToDec(Wire.read());
    *hour = bcdToDec(Wire.read() & 0x3f);
    *dayOfWeek = bcdToDec(Wire.read());
    *dayOfMonth = bcdToDec(Wire.read());
    *month = bcdToDec(Wire.read());
    *year = bcdToDec(Wire.read());
}

void displayTime(){
    byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
    // retrieve data from DS3231
    readDS3231time(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);
    // send it to the serial monitor
    Serial.print(hour, DEC);
    // convert the byte variable to a decimal number when displayed
    Serial.print(":");
    if (minute<10){
        Serial.print("0");
    }
    Serial.print(minute, DEC);
    Serial.print(":");
    if (second<10){
        Serial.print("0");
    }
    Serial.print(second, DEC);
    Serial.print(" ");
    Serial.print(dayOfMonth, DEC);
    Serial.print("/");
    Serial.print(month, DEC);
    Serial.print("/");
    Serial.print(year, DEC);
    Serial.print(" Day of week: ");
    switch(dayOfWeek){
        case 1:
            Serial.println("Sunday");
            break;
        case 2:
            Serial.println("Monday");
            break;
        case 3:
            Serial.println("Tuesday");
            break;
        case 4:
            Serial.println("Wednesday");
            break;
        case 5:
            Serial.println("Thursday");
            break;
        case 6:
            Serial.println("Friday");
            break;
        case 7:
            Serial.println("Saturday");
            break;
    }
}

void loop(){
    displayTime(); // display the real-time clock data on the Serial Monitor,
    delay(1000); // every second
}

Není právě krátký, můžete si jej ale rozdělit na několik částí, se kterými se vám bude snadno pracovat.

První část se týká knihovny Wire, která se používá pro komunikaci přes sběrnici I2C, a definování adresy sběrnice pro RTC v podobě 0x68. Následují dvě funkce, které konvertují desítková čísla do BCD (binárního kódu) a naopak. Je to nutné, protože RTC ICs fungují v BCD, ne v desítkovém systému.

Funkce setDS3231time() slouží k nastavení hodin. Je to snadné, zkrátka zadejte hodnoty od roku po sekundu a RTC od zadaného času začne počítat. Pokud například chcete nastavit středu 26. Listopadu 2014, 21:42 a 30 vteřin, použijte:

setDS3231time(30,42,21,4,26,11,14);

Čas se nastavuje ve čtyřiadvacetihodinovém rámci, kdy čtvrtým parametrem je „den v týdnu“, který značí čísla 1 až 7 (od neděle po sobotu). Tyto parametry jsou pro údaje v bytech, pokud chcete nahrazovat vlastními proměnnými.

Jakmile zprovozníte funkci, je na místě k ní přidat // (zakomentovat ji) a znovu nahrát kód, aby neresetovala čas po každém spuštění programu.

Čtení času z RTC je rovněž jednoduché, celý proces snadno sledujete pomocí funkce displayTime(). Potřebujete definovat sedm bytových proměnných, abyste mohli ukládat data z RTC a ta potom vkládáte do funkce readDS3231time().

Když máte například tyto proměnné:

byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;

… obnovit se současnými daty z RTC je můžete pomocí:

readDS3232time(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);

Pak můžete užívat proměnné, jak se vám bude hodit, např. posílat čas a datum do sériového monitoru jako sketech, který jsme použili jako příklad nebo konvertovat data do přijatelné podoby z celé řady výstupních nástrojů.

Pro ověření, že vše funguje, jak má, zadejte správný časový údaj do ukázkového sketche, nahrajte jej, zakomentujte funkci setDS3231time() a znovu ji nahrajte. Následně otevřete sériový monitor a měli byste vidět běžící displej s aktuálním časem a datem, například:

Sketch: data a časy

Nyní máte softwarové nástroje pro nastavení dat a jejich opětovné získávání z modulu RTC a my doufáme, že nyní chápete, jak tyto nepříliš nákladné moduly používat.

Více se o konkrétních RTC – DS1307 a DS3231 – dozvíte na webových stránkách výrobce.

Přeloženo z http://tronixstuff.com/2014/12/01/tutorial-using-ds1307-and-ds3231-real-time-clock-modules-with-arduino/ a mírně upraveno.

• About
• Latest Posts

Antonín Handl

Působí v časopise PLAV – měsíčník pro světovou literaturu, kde nyní jako zástupce šéfredaktora odpovídá především za propagaci a správu sociálních sítí. Příležitostně překládá odbornou literaturu a soustavně se věnuje ilustraci a grafickým návrhům. Zajímá se o open source a DIY projekty, crowdfunding a alternativní marketing.

Latest posts by Antonín Handl (see all)

• Hra o Arduino - 25.9.2015
• Měřte znečištění. S Arduinem a z obýváku. - 18.7.2015
• Turris: od výzkumného projektu ke komerční výrobě - 4.7.2015